我想知道是否可以使用推力库按键排序,而无需创建向量来存储键(即时).例如,我有以下两个向量：键和值：

vectorKeys:    0,  1,  2,  0,  1,  2,  0,  1,  2 

VectorValues: 10, 20, 30, 40, 50, 60, 70, 80, 90

按键排序后：

thrust::sort_by_key(vKeys.begin(), vKeys.end(), vValues.begin());

结果向量为：

vectorKeys:    0,  0,  0,  1,  1,  1,  2,  2,  2 

VectorValues: 10, 40, 70, 20, 50, 80, 30, 60, 90

我想知道是否可以在不需要vKeys向量的情况下(即时)进行sort_by_key的存储,因此我可以节省存储它的内存并能够对更多数据进行排序？

最后,我想按相同的键求和并存储在向量中……是否有更好的方法代替按键排序,然后按键减少以获得相同的结果？

FinalVector = 120, 150, 180  

解决方法:

原始推力示例you linked在具有行主要存储的基础数据集上执行了行总和.您的问题本质上是当基础存储为专栏存储时如何做同样的事情.

我们可以使用本质上相同的方法,但是我们必须使用置换迭代器将基础的主要列存储“动态”转换为主要行存储.

为此,我们可以借用我描述的here的函子.

这是一个完整的示例：

$cat t466.cu
#include <thrust/host_vector.h>
#include <thrust/device_vector.h>
#include <thrust/reduce.h>
#include <thrust/functional.h>
#include <thrust/sequence.h>
#include <thrust/iterator/transform_iterator.h>
#include <thrust/iterator/permutation_iterator.h>
#include <thrust/iterator/counting_iterator.h>
#include <iostream>

#define COLS 3
#define ROWS 3
#define DSIZE (COLS*ROWS)
#define INIT 10
#define STEP 10

// convert a linear index to a row index
template <typename T>
struct linear_index_to_row_index : public thrust::unary_function<T,T>
{
  T C; // number of columns

  __host__ __device__
  linear_index_to_row_index(T C) : C(C) {}

  __host__ __device__
  T operator()(T i)
  {
    return i % C;
  }
};

struct rm2cm_idx_functor : public thrust::unary_function<int, int>
{
  int r;
  int c;

  rm2cm_idx_functor(int _r, int _c) : r(_r), c(_c) {};

  __host__ __device__
  int operator() (int idx)  {
    unsigned my_r = idx/c;
    unsigned my_c = idx%c;
    return (my_c * r) + my_r;
  }
};


int main(void)
{
  int C = COLS;     // number of columns
  int R = ROWS;     // number of rows
  thrust::host_vector<int> h_vals(DSIZE);
  // initialize data
  thrust::sequence(h_vals.begin(), h_vals.end(), INIT, STEP);
  thrust::device_vector<int> vals = h_vals;
  std::cout << " Initial data: " << std::endl;
  thrust::copy(h_vals.begin(), h_vals.end(), std::ostream_iterator<int>(std::cout, ","));
  std::cout << std::endl;
  // allocate storage for row sums and indices
  thrust::device_vector<int> row_sums(R);
  thrust::device_vector<int> row_indices(R);

  // compute row sums by summing values with equal row indices
  thrust::reduce_by_key
    (thrust::make_permutation_iterator(thrust::make_transform_iterator(thrust::counting_iterator<int>(0), linear_index_to_row_index<int>(R)), thrust::make_transform_iterator(thrust::counting_iterator<int>(0), rm2cm_idx_functor(R, C))),
     thrust::make_permutation_iterator(thrust::make_transform_iterator(thrust::counting_iterator<int>(0), linear_index_to_row_index<int>(R)) + (R*C), thrust::make_transform_iterator(thrust::counting_iterator<int>(0), rm2cm_idx_functor(R, C)) + (R*C)),
     thrust::make_permutation_iterator(vals.begin(), thrust::make_transform_iterator(thrust::counting_iterator<int>(0), rm2cm_idx_functor(R, C))),
     row_indices.begin(),
     row_sums.begin(),
     thrust::equal_to<int>(),
     thrust::plus<int>());

  // print data
  thrust::host_vector<int> h_row_sums = row_sums;
  std::cout << " Results: " << std::endl;
  thrust::copy(h_row_sums.begin(), h_row_sums.end(), std::ostream_iterator<int>(std::cout, ","));
  std::cout << std::endl;
  return 0;
}

$nvcc -arch=sm_20 -o t466 t466.cu
$./t466
 Initial data:
10,20,30,40,50,60,70,80,90,
 Results:
120,150,180,
$

请注意,我还更改了linear_index_to_row_index函数,为我提供了适合于基础列主存储的行索引(当基础存储被假定为行主时,前一个函子返回了索引).这仅涉及将除法运算更改为模运算,然后传递R而不是C来初始化函子,因此请注意细微差别.