用多媒体库 Bass.dll 播放 mp3 [10] - 使用回调函数

本例效果图:

---

代码文件:

---

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls, ComCtrls;

type
  TForm1 = class(TForm)
    OpenDialog1: TOpenDialog;
    TrackBar1: TTrackBar;
    Timer1: TTimer;
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure Timer1Timer(Sender: TObject);
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

uses Bass;

var
  hs: HSTREAM;  {流句柄}

{回调函数: MySync1; 尽管没有用到其中的任何参数, 但也要按指定的参数格式来写}
procedure MySync1(handle: HSYNC; channel, data, user: DWORD); stdcall;
begin
  Form1.Text := '开始播放了';
end;

{回调函数: MySync2}
{参数1: 是回调句柄, 它可有 BASS_ChannelSetSync 返回, 并可用 BASS_ChannelRemoveSync 删除}
{参数2: 流句柄}
{参数3: 不知道}
{参数4: 是 BASS_ChannelSetSync 指定的用户数据}
procedure MySync2(handle: HSYNC; channel, data, user: DWORD); stdcall;
begin
  Form1.Text := '已过中点';
  {假如播放到此(中间点)就从头反复, 可以这样:}
  //BASS_ChannelPlay(channel, True);
end;

{回调函数: MySync3; 尽管没有用到其中的任何参数, 但也必须按要求指定}
procedure MySync3(handle: HSYNC; channel, data, user: DWORD); stdcall;
begin
  Form1.Text := '播放完毕';
end;

{初始化}
procedure TForm1.FormCreate(Sender: TObject);
begin
  TrackBar1.Height := 23;
  Timer1.Enabled := False;
  Timer1.Interval := 100;

  if HiWord(BASS_GetVersion) <> BASSVERSION then
    MessageBox(0, '"Bass.dll" 文件版本不合适! ', nil, MB_ICONERROR);

  if not BASS_Init(-1, 44100, 0, 0, nil) then ShowMessage('初始化错误');
end;

{打开}
procedure TForm1.Button1Click(Sender: TObject);
var
  Mp3Path: AnsiString;
  Mp3Len: Cardinal;
begin
  BASS_StreamFree(hs);
  Timer1.Enabled := False;

  OpenDialog1.Filter := 'Mp3 文件(*.mp3)|*.mp3|Wav 文件(*.wav)|*wav';
  if OpenDialog1.Execute then
    Mp3Path := AnsiString(OpenDialog1.FileName);

  hs := BASS_StreamCreateFile(False, PAnsiChar(Mp3Path), 0, 0, 0);
  if hs < BASS_ERROR_ENDED then
    Text := '打开失败'
  else begin
    Text := string(Mp3Path);

    {先获取流的字节总长度, 下面有用}
    Mp3Len := BASS_ChannelGetLength(hs, BASS_POS_BYTE);
    TrackBar1.Max := Mp3Len;

    {开始播放是回调 MySync1}
    {参数1: 流句柄; 参数2: 参数类型; 参数3: 参数值; 参数4: 要回调函数指针; 参数5: 用户数据}
    BASS_ChannelSetSync(hs, BASS_SYNC_POS, 0, @MySync1, nil);

    {播放到中间时回调 MySync2}
    BASS_ChannelSetSync(hs, BASS_SYNC_POS, Mp3Len div 2, @MySync2, nil);

    {播放结束时回调 MySync3}
    BASS_ChannelSetSync(hs, BASS_SYNC_END, 0, @MySync3, nil);
    {当然也可以写做:}
    //BASS_ChannelSetSync(hs, BASS_SYNC_POS, Mp3Len, @MySync3, nil);
    {如果第二个参数同时指定 BASS_SYNC_ONETIME, 回调函数将只执行一次}
    BASS_ChannelSetSync(hs, BASS_SYNC_END or BASS_SYNC_ONETIME, 0, @MySync3, nil);
  end;
end;

{播放}
procedure TForm1.Button2Click(Sender: TObject);
begin
  BASS_ChannelPlay(hs, False);
  Timer1.Enabled := True;
end;

{暂停}
procedure TForm1.Button3Click(Sender: TObject);
begin
  BASS_ChannelPause(hs);
  Timer1.Enabled := False;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  BASS_Free;
end;

procedure TForm1.Timer1Timer(Sender: TObject);
begin
  if BASS_ChannelIsActive(hs) = BASS_ACTIVE_PLAYING then
    TrackBar1.Position := BASS_ChannelGetPosition(hs, BASS_POS_BYTE);
end;

end.

窗体文件:

---

object Form1: TForm1
  Left = 222
  Top = 114
  Caption = 'Form1'
  ClientHeight = 84
  ClientWidth = 254
  Color = clBtnFace
  Font.Charset = DEFAULT_CHARSET
  Font.Color = clWindowText
  Font.Height = -11
  Font.Name = 'Tahoma'
  Font.Style = []
  OldCreateOrder = False
  Position = poDesigned
  OnCreate = FormCreate
  OnDestroy = FormDestroy
  PixelsPerInch = 96
  TextHeight = 13
  object Button1: TButton
    Left = 8
    Top = 18
    Width = 75
    Height = 25
    Caption = #25171#24320
    TabOrder = 0
    OnClick = Button1Click
  end
  object Button2: TButton
    Left = 89
    Top = 18
    Width = 75
    Height = 25
    Caption = #25773#25918
    TabOrder = 1
    OnClick = Button2Click
  end
  object Button3: TButton
    Left = 170
    Top = 18
    Width = 75
    Height = 25
    Caption = #26242#20572
    TabOrder = 2
    OnClick = Button3Click
  end
  object TrackBar1: TTrackBar
    Left = 1
    Top = 53
    Width = 250
    Height = 28
    TabOrder = 3
  end
  object OpenDialog1: TOpenDialog
    Left = 72
    Top = 32
  end
  object Timer1: TTimer
    OnTimer = Timer1Timer
    Left = 152
    Top = 32
  end
end

posted on 2008-08-21 13:14  万一  阅读(4172)  评论(0)  编辑  收藏