一、匹配数字

实现的效果：(点击右边“提取数字”按钮)

实现的代码：

Sub 提取数字()
Dim cell As Range
Dim sj As Object
Dim regx As Object
Dim ss As Object
Dim n As Integer

'创建了一个 VBScript 正则表达式对象 regx，用于匹配特定模式的字符串
Set regx = CreateObject("vbscript.regexp")
'设置正则表达式属性
With regx
    .Global = True  '表示正则表达式会在字符串中查找所有匹配项，而不仅仅是一个匹配项
    .Pattern = "\d+" '定义了正则表达式模式 \d+，用于匹配一个或多个数字字符
    For Each cell In Range("a2", Cells(Rows.Count, 1).End(xlUp))
        '对当前单元格内容进行正则表达式匹配，并将所有匹配结果存入 sj 集合中
        Set sj = .Execute(cell)
        For Each ss In sj
            '每找到一个匹配项，就将 n 递增 1，用于确定数据写入的位置
            n = n + 1
            '将匹配的数字写入当前行中的下一个单元格.Offset(0, n)指定了写入的位置：与 ss 单元格在同一行，向右偏移 n 列
            cell.Offset(0, n) = ss
        Next ss
        '在处理完当前单元格后，将 n 重置为 0，以便在下一行重新开始
        n = 0
    Next cell
End With
End Sub

 二、匹配字母+数字

 
实现的效果：

实现的代码：

Sub 项目编号()
Dim cell As Range
Dim sj As Object
Dim regx As Object
Dim ss As Object
Dim n As Integer

Set regx = CreateObject("vbscript.regexp")
With regx
    .Global = True
    '[a-zA-Z]+\d+，用于匹配一个或多个英文字母后面紧跟一个或多个数字的字符串(如:abc123)
    .Pattern = "[a-zA-Z]+\d+"
    For Each cell In Range("a2", Cells(Rows.Count, 1).End(xlUp))
    Set sj = .Execute(cell)
        For Each ss In sj
            cell.Offset(0, 1) = ss
            '将匹配的结果替换成空(:将cell中的匹配部分去掉,保留剩余的内容,并将其写入相应单元格)
            cell.Offset(0, 2) = .Replace(cell, "")
        Next ss
    Next cell
End With
End Sub

三、两个代码区别就是.Pattern里面的内容(和你想要匹配的有关)