一、创建数据库

#1.创建一个数据库，数据库在HDFS上的默认存储路径是/user/hive/warehouse/*.db。
hive (default)> create database db_hive;

#2.避免要创建的数据库已经存在错误，增加if not exists判断。（标准写法）
hive (default)> create database if not exists db_hive;

#3.创建一个数据库，指定数据库在HDFS上存放的位置
hive (default)> create database db_hive2 location '/db_hive2.db';

二、修改数据库

用户可以使用ALTER DATABASE命令为某个数据库的DBPROPERTIES设置键-值对属性值，来描述这个数据库的属性信息。数据库的其他元数据信息都是不可更改的，包括数据库名和数据库所在的目录位置。
#1.修改数据库
hive (default)> alter database db_hive set dbproperties('createtime'='20210816');

#2.查看修改结果
hive> desc database extended db_hive;
db_name comment location        owner_name      owner_type      parameters
db_hive         hdfs://localhost:8020/user/hive/warehouse/db_hive.db    atguigu USER    {createtime=20210816}

三、查询数据库

#1.显示数据库
hive> show databases;

#2.过滤显示查询的数据库
hive> show databases like 'db_hive*';
OK
db_hive
db_hive_1

#3.显示数据库信息
hive> desc database db_hive;
OK
db_hive hdfs://localhost:8020/user/hive/warehouse/db_hive.db atguiguUSER 

#4.显示数据库详细信息，extended
hive> desc database extended db_hive;
OK
db_hive hdfs://localhost:8020/user/hive/warehouse/db_hive.db atguiguUSER

#5.切换当前数据库
hive (default)> use db_hive;

四、删除数据库

#1.删除空数据库
hive>drop database db_hive2;

#2.如果删除的数据库不存在，最好采用 if exists判断数据库是否存在
hive> drop database db_hive2;
FAILED: SemanticException [Error 10072]: Database does not exist: db_hive
hive> drop database if exists db_hive2;

#3.如果数据库不为空，可以采用cascade命令，强制删除
hive> drop database db_hive;
FAILED: Execution Error, return code 1 from org.apache.hadoop.hive.ql.exec.DDLTask. InvalidOperationException(message:Database db_hive is not empty. One or more tables exist.)
hive> drop database db_hive cascade;

五、创建表

#1.建表语法
CREATE [EXTERNAL] TABLE [IF NOT EXISTS] table_name 
[(col_name data_type [COMMENT col_comment], ...)] 
[COMMENT table_comment] 
[PARTITIONED BY (col_name data_type [COMMENT col_comment], ...)] 
[CLUSTERED BY (col_name, col_name, ...) 
[SORTED BY (col_name [ASC|DESC], ...)] INTO num_buckets BUCKETS] 
[ROW FORMAT row_format] 
[STORED AS file_format] 
[LOCATION hdfs_path]

#2.字段解释说明：
1.CREATE TABLE 创建一个指定名字的表。如果相同名字的表已经存在，则抛出异常；用户可以用 IF NOT EXISTS 选项来忽略这个异常。

2.EXTERNAL关键字可以让用户创建一个外部表，在建表的同时指定一个指向实际数据的路径（LOCATION），Hive创建内部表时，会将数据移动到数据仓库指向的路径；若创建外部表，仅记录数据所在的路径，不对数据的位置做任何改变。在删除表的时候，内部表的元数据和数据会被一起删除，而外部表只删除元数据，不删除数据。

3.COMMENT：为表和列添加注释。

4.PARTITIONED BY创建分区表

5.CLUSTERED BY创建分桶表

6.SORTED BY不常用

7.ROW FORMAT

DELIMITED [FIELDS TERMINATED BY char] [COLLECTION ITEMS TERMINATED BY char]
[MAP KEYS TERMINATED BY char] [LINES TERMINATED BY char]
| SERDE serde_name [WITH SERDEPROPERTIES (property_name=property_value, property_name=property_value, …)]
用户在建表的时候可以自定义SerDe或者使用自带的SerDe。如果没有指定ROW FORMAT 或者ROW FORMAT DELIMITED，将会使用自带的SerDe。在建表的时候，用户还需要为表指定列，用户在指定表的列的同时也会指定自定义的SerDe，Hive通过SerDe确定表的具体的列的数据。

8.STORED AS指定存储文件类型
常用的存储文件类型：SEQUENCEFILE（二进制序列文件）、TEXTFILE（文本）、RCFILE（列式存储格式文件）
如果文件数据是纯文本，可以使用STORED AS TEXTFILE。如果数据需要压缩，使用 STORED AS SEQUENCEFILE。

9.LOCATION ：指定表在HDFS上的存储位置。

10.LIKE允许用户复制现有的表结构，但是不复制数据。

六、管理表

1.概念

默认创建的表都是所谓的管理表，有时也被称为内部表。因为这种表，Hive会（或多或少地）控制着数据的生命周期。Hive默认情况下会将这些表的数据存储在由配置项hive.metastore.warehouse.dir(例如，/user/hive/warehouse)所定义的目录的子目录下。 当我们删除一个管理表时，Hive也会删除这个表中数据。管理表不适合和其他工具共享数据。

2.管理表基本操作

# 1.普通创建表
create table if not exists student2(
id int, name string
)
row format delimited fields terminated by '\t'
stored as textfile
location '/user/hive/warehouse/student2';

#2.根据查询结果创建表（查询的结果会添加到新创建的表中）
create table if not exists student3
as select id, name from student;

#3.根据已经存在的表结构创建表
create table if not exists student4 like student;

3.查询表的类型

hive (default)> desc formatted student2;
Table Type:             MANAGED_TABLE  

七、外部表

1.概念

#1.外部表：
因为表是外部表，所以Hive并非认为其完全拥有这份数据。删除该表并不会删除掉这份数据，不过描述表的元数据信息会被删除掉。

#2.管理表和外部表的使用场景：
每天将收集到的网站日志定期流入HDFS文本文件。在外部表（原始日志表）的基础上做大量的统计分析，用到的中间表、结果表使用内部表存储，数据通过SELECT+INSERT进入内部表。

2.外部表基本操作

#1.创建部门表
create external table if not exists default.dept(
deptno int,
dname string,
loc int
)
row format delimited fields terminated by '\t';

#2.创建员工表
create external table if not exists default.emp(
empno int,
ename string,
job string,
mgr int,
hiredate string, 
sal double, 
comm double,
deptno int)
row format delimited fields terminated by '\t';

#3.查看创建的表
hive (default)> show tables;
OK
tab_name
dept
emp

#4.向外部表中导入数据
1.导入数据
hive (default)> load data local inpath '/data/dept.txt' into table default.dept;
hive (default)> load data local inpath '/data/emp.txt' into table default.emp;

2.查询结果
hive (default)> select * from emp;
hive (default)> select * from dept;

3.查看表格式化数据
hive (default)> desc formatted dept;
Table Type:             EXTERNAL_TABLE

八、分区表

1.概念

分区表实际上就是对应一个HDFS文件系统上的独立的文件夹，该文件夹下是该分区所有的数据文件。Hive中的分区就是分目录，把一个大的数据集根据业务需要分割成小的数据集。在查询时通过WHERE子句中的表达式选择查询所需要的指定的分区，这样的查询效率会提高很多。

2.分区表基本操作

#1.引入分区表（需要根据日期对日志进行管理）
/user/hive/warehouse/log_partition/20210702/20210702.log
/user/hive/warehouse/log_partition/20210703/20210703.log
/user/hive/warehouse/log_partition/20210704/20210704.log

#2.创建分区表语法
hive (default)> create table dept_partition(
               deptno int, dname string, loc string
               )
               partitioned by (month string)
               row format delimited fields terminated by '\t';

#3.加载数据到分区表中
hive (default)> load data local inpath '/datadept.txt' into table default.dept_partition partition(month='202109');
hive (default)> load data local inpath '/datadept.txt' into table default.dept_partition partition(month='202108');
hive (default)> load data local inpath '/datadept.txt' into table default.dept_partition partition(month='202107');

#4.查询分区表中数据
1.单分区查询
hive (default)> select * from dept_partition where month='202109';

2.多分区联合查询
hive (default)> select * from dept_partition where month='202109'
              union
              select * from dept_partition where month='202108'
              union
              select * from dept_partition where month='202107';

_u3.deptno      _u3.dname       _u3.loc _u3.month
10      ACCOUNTING      NEW YORK        202107
10      ACCOUNTING      NEW YORK        202108
10      ACCOUNTING      NEW YORK        202109
20      RESEARCH        DALLAS  202107
20      RESEARCH        DALLAS  202108
20      RESEARCH        DALLAS  202109
30      SALES   CHICAGO 202107
30      SALES   CHICAGO 202108
30      SALES   CHICAGO 202109
40      OPERATIONS      BOSTON  202107
40      OPERATIONS      BOSTON  202108
40      OPERATIONS      BOSTON  202109

#5.增加分区
1.创建单个分区
hive (default)> alter table dept_partition add partition(month='202106') ;
2.同时创建多个分区
hive (default)>  alter table dept_partition add partition(month='202105') partition(month='202104');

#6.删除分区
1.删除单个分区
hive (default)> alter table dept_partition drop partition (month='202104');
2.同时删除多个分区
hive (default)> alter table dept_partition drop partition (month='202105'), partition (month='202106');

#7.查看分区表有多少分区
hive>show partitions dept_partition;

#8.查看分区表结构
hive>desc formatted dept_partition;
# Partition Information          
# col_name              data_type               comment             
month                   string    

3.分区表注意事项

#1.创建二级分区表
hive (default)> create table dept_partition2(
               deptno int, dname string, loc string
               )
               partitioned by (month string, day string)
               row format delimited fields terminated by '\t';
               
#2.正常的加载数据
（1）加载数据到二级分区表中
hive (default)> load data local inpath '/data/dept.txt' into table default.dept_partition2 partition(month='202109', day='13');
（2）查询分区数据
hive (default)> select * from dept_partition2 where month='202109' and day='13';

#3.把数据直接上传到分区目录上，让分区表和数据产生关联的两种方式
（1）方式一：上传数据后修复
上传数据
hive (default)> dfs -mkdir -p /user/hive/warehouse/dept_partition2/month=202109/day=12;
hive (default)> dfs -put /datadept.txt  /user/hive/warehouse/dept_partition2/month=202109/day=12;

查询数据（查询不到刚上传的数据）
hive (default)> select * from dept_partition2 where month='202109' and day='12';

执行修复命令
hive>msck repair table dept_partition2;

再次查询数据
hive (default)> select * from dept_partition2 where month='202109' and day='12';

（2）方式二：上传数据后添加分区
上传数据
hive (default)> dfs -mkdir -p /user/hive/warehouse/dept_partition2/month=202109/day=11;
hive (default)> dfs -put /datadept.txt  /user/hive/warehouse/dept_partition2/month=202109/day=11;

执行添加分区
hive (default)> alter table dept_partition2 add partition(month='202109', day='11');

查询数据
hive (default)> select * from dept_partition2 where month='202109' and day='11';

（3）方式三：上传数据后load数据到分区
创建目录
hive (default)> dfs -mkdir -p /user/hive/warehouse/dept_partition2/month=202109/day=10;

上传数据
hive (default)> load data local inpath '/datadept.txt' into table dept_partition2 partition(month='202109',day='10');

查询数据
hive (default)> select * from dept_partition2 where month='202109' and day='10';

九、修改表

1.重命名表

#1.语法
ALTER TABLE table_name RENAME TO new_table_name

#2.实操案例
hive (default)> alter table dept_partition2 rename to dept_partition3;

2.增加/修改/替换列信息

#1.更新列语法
ALTER TABLE table_name CHANGE [COLUMN] col_old_name col_new_name column_type [COMMENT col_comment] [FIRST|AFTER column_name]

#2.增加和替换列语法
ALTER TABLE table_name ADD|REPLACE COLUMNS (col_name data_type [COMMENT col_comment], ...) 

注：ADD是代表新增一字段，字段位置在所有列后面(partition列前)，REPLACE则是表示替换表中所有字段。

#3.查询表结构
hive>desc dept_partition;

#4.添加列
hive (default)> alter table dept_partition add columns(deptdesc string);

#5.查询表结构
hive>desc dept_partition;

#6.更新列
hive (default)> alter table dept_partition change column deptdesc desc int;

#7.查询表结构
hive>desc dept_partition;

#8.替换列
hive (default)> alter table dept_partition replace columns(deptno string, dname string, loc string);

#9.查询表结构
hive>desc dept_partition;

#10.删除表
hive (default)> drop table dept_partition;

十、DML数据操作

1.数据导入

向表中装载数据（Load）
#1.语法
hive>load data [local] inpath '/data/student.txt' [overwrite] into table student [partition (partcol1=val1,…)];

#2.语法解释
1.load data:表示加载数据
2.local:表示从本地加载数据到hive表；否则从HDFS加载数据到hive表
3.inpath:表示加载数据的路径
4.overwrite:表示覆盖表中已有数据，否则表示追加
5.into table:表示加载到哪张表
6.student:表示具体的表
7.partition:表示上传到指定分区

#3.实例
1.创建一张表
hive (default)> create table student(id string, name string) row format delimited fields terminated by '\t';

2.加载本地文件到hive
hive (default)> load data local inpath '/data/student.txt' into table default.student;

3.加载HDFS文件到hive中
上传文件到HDFS
hive (default)> dfs -put /data/student.txt /user/atguigu/hive;
加载HDFS上数据
hive (default)>load data inpath '/user/atguigu/hive/student.txt' into table default.student;

4.加载数据覆盖表中已有的数据
上传文件到HDFS
hive (default)> dfs -put /datastudent.txt /user/atguigu/hive;
加载数据覆盖表中已有的数据
hive (default)>load data inpath '/user/atguigu/hive/student.txt' overwrite into table default.student;

2.通过查询语句向表中插入数据（Insert）

#1.创建一张分区表
hive (default)> create table student(id int, name string) partitioned by (month string) row format delimited fields terminated by '\t';

#2.基本插入数据
hive (default)> insert into table  student partition(month='202109') values(1,'wangwu');

#3.基本模式插入（根据单张表查询结果）
hive (default)> insert overwrite table student partition(month='202108')
             select id, name from student where month='202109';

#4.多插入模式（根据多张表查询结果）
hive (default)> from student
              insert overwrite table student partition(month='202107')
              select id, name where month='202109'
              insert overwrite table student partition(month='202106')
              select id, name where month='202109';
              
#5.查询语句中创建表并加载数据（As Select）
create table if not exists student3
as select id, name from student;

#6.创建表时通过Location指定加载数据路径
1.创建表，并指定在hdfs上的位置
hive (default)> create table if not exists student5(
              id int, name string
              )
              row format delimited fields terminated by '\t'
              location '/user/hive/warehouse/student5';

2.上传数据到hdfs上
hive (default)> dfs -put /datastudent.txt  /user/hive/warehouse/student5;

3.查询数据
hive (default)> select * from student5;

3.Import数据到指定Hive表中

ps：先用export导出后，再将数据导入。

hive (default)> import table student2 partition(month='202109') from '/user/hive/warehouse/export/student';

#1.Insert导出
1.将查询的结果导出到本地
hive (default)> insert overwrite local directory '/dataexport/student'
            select * from student;

2.将查询的结果格式化导出到本地
hive (default)> insert overwrite local directory '/dataexport/student1'
             ROW FORMAT DELIMITED FIELDS TERMINATED BY '\t'             select * from student;

3.将查询的结果导出到HDFS上(没有local)
hive (default)> insert overwrite directory '/user/atguigu/student2'
             ROW FORMAT DELIMITED FIELDS TERMINATED BY '\t' 
             select * from student;

#2.Hadoop命令导出到本地
hive (default)> dfs -get /user/hive/warehouse/student/month=202109/000000_0  /dataexport/student3.txt;

#3.Hive Shell 命令导出
1.基本语法：（hive -f/-e 执行语句或者脚本 > file）
[root@stg-airflow001 hive]$ hive -e 'select * from default.student;' > /dataexport/student4.txt;

2.Export导出到HDFS上
hive (default)> export table default.student to '/user/hive/warehouse/export/student';

#4.清除表中数据（Truncate）
注意：Truncate只能删除管理表，不能删除外部表中数据
hive (default)> truncate table student;