1. 如何修改打包好的apk名称

Android Studio从2.0升级到3.0之后，要修改打包后的apk名称，必须采用以下配置：

android {
    ...
    
    applicationVariants.all {variant ->
        variant.outputs.all {output ->
            if (variant.buildType.name == "debug") {
                output.outputFileName = "iou_v${android.defaultConfig.versionName}_debug_${getCurrentTime()}.apk"
            } else if (variant.buildType.name == "release") {
                output.outputFileName = "iou_v${android.defaultConfig.versionName}_release_${getCurrentTime()}.apk"
            }
        }
    }
}

//获取当前时间
def getCurrentTime() {
    return new Date().format("yyyy-MM-dd HH:mm:ss")
}

以我自己的某个工程为例，最终打出的一个debug包如下：

iou_v1.1.6.1_debug_2018-10-17 17:11:36.apk

这断配置的核心是设置output.outputFileName，鼠标点上去可以发现，这个output对象是BaseVariantOutput类型的，但是我们查看BaseVariantOutput的代码，发现死活找不到outputFileName属性，这样就很令人费解了，网上找了一圈也没相关资料介绍。
秉着刨根究底的精神，我们看看这个output到底是个什么鬼？采用以下代码在控制台打印出来看看：

  println output 
  Field[] fields = output.getClass().getDeclaredFields()
  fields.each { field ->
      println field.name
  }

ApkVariantOutputImpl_Decorated{apkData=Main{type=MAIN, fullName=debug, filters=[]}}
__dyn_obj__
__meta_class__
__mapping__
__apkData__
__assemble__
__baseName__
__dirName__
__filterTypes__
__filters__
__mainOutputFile__
__name__
__outputFile__
__outputFileName__
__outputType__
__outputs__
__packageApplication__
__processManifest__
__processResources__
__versionCode__
__versionCodeOverride__
__versionNameOverride__
__zipAlign__

可以看到这个output的真实类型是ApkVariantOutputImpl_Decorated，里面有个属性__outputFileName__，这其实是个装饰类，它真正的类型是ApkVariantOutput，outputFileName就是ApkVariantOutput里的属性值。

2. 如何打包完成后将apk复制到指定目录

我们做持续集成的时候，自动打包之后，可能会需要将包复制到指定的目录。

project.tasks.all {task ->
    if ("assembleDebug" == task.name || "assembleRelease" == task.name) {
        //在打包完成之后，增加一个任务
        task.doLast {
            println "====${task.name} doLast===="
            android.applicationVariants.all { variant ->
                variant.outputs.all { output ->
                    def apkFile = output.outputFile
                    //如果目标文件存在
                    if (apkFile.exists()) {
                        //将apk文件复制到桌面去
                        copy {
                            from apkFile.getCanonicalPath()
                            into "/Users/hjy/Desktop"
                        }
                        //复制到指定目录后删除原文件
                        delete(apkFile)
                    }
                }
            }
       }
    }
}