SELECT  表名=CASE WHEN C.column_id=1 THEN O.name ELSE N'' END,

       表描述=ISNULL(CASE WHEN C.column_id=1 THEN PTB.[value] END,N''),

       字段序号=C.column_id,

       字段名称=C.name,

       字段描述=ISNULL(PFD.[value],N''),

       主键=ISNULL(IDX.PrimaryKey,N''),

       是否递增=CASE WHEN C.is_identity=1 THEN N'√'ELSE N'' END,

       是否计算=CASE WHEN C.is_computed=1 THEN N'√'ELSE N'' END,

       数据类型=T.name,

       最大长度=C.max_length,

       数据长度=C.precision,

       小数长度=C.scale,

       允许空值=CASE WHEN C.is_nullable=1 THEN N'√'ELSE N'' END,

       默认值=ISNULL(D.definition,N''),

       索引名称=ISNULL(IDX.IndexName,N''),

       索引类型=ISNULL(IDX.Sort,N''),

       创建日期=O.Create_Date,

       修改日期=O.Modify_date

FROM sys.columns C

INNER JOIN sys.objects O ON C.[object_id]=O.[object_id]

       AND O.type='U'

       AND O.is_ms_shipped=0

INNER JOIN sys.types T ON C.user_type_id=T.user_type_id

LEFT JOIN sys.default_constraints D ON C.[object_id]=D.parent_object_id

       AND C.column_id=D.parent_column_id

       AND C.default_object_id=D.[object_id]

LEFT JOIN sys.extended_properties PFD ON PFD.class=1

       AND C.[object_id]=PFD.major_id

       AND C.column_id=PFD.minor_id

LEFT JOIN sys.extended_properties PTB ON PTB.class=1

       AND PTB.minor_id=0

       AND C.[object_id]=PTB.major_id

LEFT JOIN

(

  SELECT IDXC.[object_id],

         IDXC.column_id,

         Sort=CASE INDEXKEY_PROPERTY(IDXC.[object_id],IDXC.index_id,IDXC.index_column_id,'IsDescending')

                WHEN 1 THEN 'DESC'

                WHEN 0 THEN 'ASC'                  ELSE ''

              END,

         PrimaryKey=CASE WHEN IDX.is_primary_key=1 THEN N'√'ELSE N'' END,

         IndexName=IDX.Name

  FROM sys.indexes IDX

  INNER JOIN sys.index_columns IDXC ON IDX.[object_id]=IDXC.[object_id]

         AND IDX.index_id=IDXC.index_id

  LEFT JOIN sys.key_constraints KC ON IDX.[object_id]=KC.[parent_object_id]

         AND IDX.index_id=KC.unique_index_id

  INNER JOIN

  (

    SELECT [object_id], Column_id, index_id=MIN(index_id)

    FROM sys.index_columns

    GROUP BY [object_id], Column_id

  ) IDXCUQ ON IDXC.[object_id]=IDXCUQ.[object_id]

         AND IDXC.Column_id=IDXCUQ.Column_id

         AND IDXC.index_id=IDXCUQ.index_id

) IDX ON C.[object_id]=IDX.[object_id]

       AND C.column_id=IDX.column_id

WHERE O.name=N'MyTableName'

ORDER BY O.name,C.column_id