实验4 8086标志寄存器及中断

2023-12-05 16:51:52

1. 实验任务1

①add指令对标志寄存器中的零标志位ZF(Zero Flag)、进位标志位CF(Carry Flag)是否有影响？

都有影响。

当相加为0时，零标志位为1，符号为ZR。当相加结果溢出时，进位标志位为1，符号为CY。

② inc指令对标志寄存器中的零标志位ZF(Zero Flag)、进位标志位CF(Carry Flag)是否有影响？

对零标志位ZF有影响，对进位标志位CF没有影响。

task1.asm源码

assume cs:code, ds:data

data segment
   x dw 1020h, 2240h, 9522h, 5060h, 3359h, 6652h, 2530h, 7031h
   y dw 3210h, 5510h, 6066h, 5121h, 8801h, 6210h, 7119h, 3912h
data ends
code segment 
start:
    mov ax, data
    mov ds, ax
    mov si, offset x
    mov di, offset y
    call add128

    mov ah, 4ch
    int 21h

add128:
    push ax
    push cx
    push si
    push di

    sub ax, ax

    mov cx, 8
s:  mov ax, [si]
    adc ax, [di]
    mov [si], ax

    inc si
    inc si
    inc di
    inc di
    loop s

    pop di
    pop si
    pop cx
    pop ax
    ret
code ends
end start

回答问题 line31~line34的4条inc指令，能否替换成如下代码？你的结论的依据/理由是什么？

替换后调试运行：

结果与原程序相同，所以可以替换。

理由：数据段个数小于si和di寄存器的最大值，所以直接加2和inc两次的结果相同。

在debug中调试，观察数据段中做128位加之前和加之后，数据段的值的变化。给出调试观察截图。

执行到初始化ds的值后数据段的值：

相加之后数据段的值：

相加结果存储在x中

2. 实验任务2

程序task2.asm源码

assume cs:code, ds:data
data segment
        str db 80 dup(?)
data ends

code segment
start:  
        mov ax, data
        mov ds, ax
        mov si, 0
s1:        
        mov ah, 1
        int 21h
        mov [si], al
        cmp al, '#'
        je next
        inc si
        jmp s1
next:
        mov ah, 2
        mov dl, 0ah
        int 21h
        
        mov cx, si
        mov si, 0
s2:     mov ah, 2
        mov dl, [si]
        int 21h
        inc si
        loop s2

        mov ah, 4ch
        int 21h
code ends
end start

运行测试截图

回答问题

运行程序，从键盘上输入一串字符，以#结束（比如，输入George Orwell, 1984#)，观察结果。结合运行结果，理解代码并回答问题：

① 汇编指令代码line11-18，实现的功能是？

从屏幕中输入字符，直到‘#’结束。

② 汇编指令代码line20-22，实现的功能是？

换行输出。

③ 汇编指令代码line24-30，实现的功能是？

将数据寄存器中的有效数值输出。

3. 实验任务3

task3.asm源码

assume cs:code, ds:data, ss:stack

data segment
    x dw 91, 792, 8536, 65521, 2021
    len equ $ - x
data ends

stack segment
    dw 16 dup(0)
stack ends

code segment
start:
    mov ax,data
    mov ds,ax
    mov ax,stack
    mov ss,ax
    mov sp,16

    mov si,0
    mov cx,5

  s1:
    call printNumber
    call printSpace
    inc si
    inc si
    loop s1

    mov ah,4ch
    int 21h

printNumber:
    push cx
    
    mov ax,[si]
    mov di,0

    s2:
    mov dx,0
    mov bx,10
    div bx
    push dx
    inc di
    mov cx,ax
    jcxz s3
    loop s2


    s3:
    mov cx,di
    s4:
    mov ah,2
    pop dx
    add dl,30h
    int 21h
    loop s4

    pop cx
    ret

printSpace:
    mov ah,2
    mov dl,' '
    int 21h
    ret

code ends
end start

运行测试截图

4. 实验任务4

task4.asm源码

assume cs:code,ds:data

data segment
    str db "assembly language, it's not difficult but tedious"
    len equ $ - str
data ends

code segment
start:
    mov ax,data
    mov ds,ax
    mov si,0
    mov cx,len

    s:
    mov al,[si]
    call strupr
    inc si
    loop s

    mov ah,4ch
    int 21h

    strupr:
    cmp al,'a'
    jb s2
    cmp al,'z'
    ja s2
    and al,11011111b
    mov [si],al

    s2:
    mov ah,2
    mov dl,al
    int 21h
    ret

code ends
end start

在debug中调试截图（ call strupr 调用之前，数据段的值，以及，调用之后，数据段的值）

call strupr 调用之前

调用之后，数据段的值

5.实验任务5

task5.asm源码

assume cs:code, ds:data

data segment
    str1 db "yes", '$'
    str2 db "no", '$'
data ends

code segment
start:
    mov ax, data
    mov ds, ax

    mov ah, 1
    int 21h

    mov ah, 2
    mov bh, 0
    mov dh, 24
    mov dl, 70
    int 10h

    cmp al, '7'
    je s1
    mov ah, 9
    mov dx, offset str2
    int 21h

    jmp over

s1: mov ah, 9
    mov dx, offset str1
    int 21h
over:  
    mov ah, 4ch
    int 21h
code ends
end start

程序运行测试截图（输入7，以及输入其他字符，运行结果截图）程序的功能是？

程序的功能是：

判断输入字符是否是7，若是则在本页的最后一行第70列开始输出yes，若不是则输出no

6. 实验任务6

通过此项实现任务，你对中断、软中断实现机制的理解

1）中断即发生中断事情时CPU马上处理中断信息，中断服务完毕后，返回到主程序被中断处继续执行。

2 ）当CPU内部发生除法错误、单步执行、执行into指令、执行int指令这四种情况时发生中断。

3）一个完整的中断基本过程包括：中断请求、中断判优、中断响应、中断处理及中断返回等五个基本过程。

4）硬中断由外部硬件产生，软中断是CPU根据软件的某些指令或软件对标志寄存器某个标志位的设置而产生的，由于它与外部中断电路完全无关。

自己选一个未被使用的中断码，实现一个中断例程，并调用测试。

给出源码和运行测试截图。(选做 *) 如选做，请说明你使用的中断码，并描述你实现的这个中断例程的功能。

源码：

中断服务：

assume cs:code

code segment
start:
    mov ax, cs
    mov ds, ax
    mov si, offset int241

    mov ax, 0
    mov es, ax
    mov di, 200h

    mov cx, offset int241_end - offset int241
    cld
    rep movsb

    mov ax, 0
    mov es, ax
    mov word ptr es:[241*4], 200h
    mov word ptr es:[241*4+2], 0

    mov ah, 4ch
    int 21h

int241: 
    jmp short int241_start
    str db "201983290108,weisai"
    len equ $ - str

int241_start:
    mov ax, cs
    mov ds, ax
    mov si, 202h

    mov ax, 0b800h
    mov es, ax
    mov di, 11*160 + 32*2

    mov cx, len
s:  mov al, [si]
    cmp al,'a'
    jb s2
    cmp al,'z'
    ja s2
    and al,11011111b
    
    s2:
    mov es:[di],al
    mov byte ptr es:[di+1], 2
    inc si
    add di, 2
    loop s

    iret
int241_end:
   nop
code ends
end start

主程序：

assume cs:code
code segment
start:
    int 241

    mov ah, 4ch
    int 21h
code ends
end start

运行测试截图：

使用的中断码为系统未使用的241，即f1h。

中断例程的功能为将字符串‘201983290108,weisai’中的小写字母转换为大写字母，并在屏幕中间黑底绿字打印。

码农公寓