实验任务1

task1.asm源码

assume cs:code, ds:data

data segment
   x dw 1020h, 2240h, 9522h, 5060h, 3359h, 6652h, 2530h, 7031h
   y dw 3210h, 5510h, 6066h, 5121h, 8801h, 6210h, 7119h, 3912h
data ends
code segment 
start:
    mov ax, data
    mov ds, ax
    mov si, offset x
    mov di, offset y
    call add128

    mov ah, 4ch
    int 21h

add128:
    push ax
    push cx
    push si
    push di

    sub ax, ax

    mov cx, 8
s:  mov ax, [si]
    adc ax, [di]
    mov [si], ax

    inc si
    inc si
    inc di
    inc di
    loop s

    pop di
    pop si
    pop cx
    pop ax
    ret
code ends
end start

（1）line31~line34的4条inc指令，能否替换成如下代码？你的结论的依据/理由是什么？

　　不能，因为inc的自增不改变标志位CF,而add指令会改变标志位CF。

（2）在debug中调试，观察数据段中做128位加之前，和，加之后，数据段值得变化

　　加之前：

 

 

 　　加之后：

 

 

 

实验任务2

task2.asm源码

assume cs:code, ds:data
data segment
        str db 80 dup(?)
data ends

code segment
start:  
        mov ax, data
        mov ds, ax
        mov si, 0
s1:        
        mov ah, 1
        int 21h
        mov [si], al
        cmp al, '#'
        je next
        inc si
        jmp s1
next:
        mov ah, 2
        mov dl, 0ah
        int 21h
        
        mov cx, si
        mov si, 0
s2:     mov ah, 2
        mov dl, [si]
        int 21h
        inc si
        loop s2

        mov ah, 4ch
        int 21h
code ends
end start

 （1）汇编指令代码line11-18，实现的功能是？

　　line11-18实现的是从键盘上逐个读取字符，直到读到#时结束

（2） 汇编指令代码line20-22，实现的功能是？

　　line20-22实现的是输出一个换行

（3）汇编指令代码line24-30，实现的功能是？

　　line24-30实现的是输出刚刚从键盘输入的#之前的字符串

截图如下：

 

实验任务3

task3.asm源码

assume cs:code, ds:data
data segment
    x dw 91, 792, 8536, 65521, 2021
    len equ $ - x
data ends

stack segment
    db 16 dup(0)
stack ends
 
code segment
start:
    mov ax, data
    mov ds, ax
    mov cx, 5
    mov si, 0
 
s1:
    mov ax, ds:[si]
    call printNumber
    call printSpace
    add si, 2
    loop s1
 
    mov ah, 4ch
    int 21h
 
printNumber:
    push cx
    mov dx, 0
    mov bx, 10
    mov di, 0
process:
    div bx
    push dx
    mov dx, 0
    inc di
    cmp ax, 0
    je  s2
    jmp process
s2:
    mov cx, di
    mov ah, 2
s3:
    pop dx
    or dl, 30h
    int 21h
    loop s3
 
    pop cx
    ret
 
printSpace:
    mov ah, 2
    mov dl, 32
    int 21h
    ret
 
code ends
end start

运行结果如下：

 

 

实验任务4

task4.asm源码

assume cs:code, ds:data
 
data segment
    str db "assembly language, it's not difficult but tedious"
    len equ $ - str
data ends
 
code segment
start:
    mov ax, data
    mov ds, ax
    mov cx, len
    mov si, 0
 
s:
    call strUp
    inc si
    loop s
 
    mov cx, len
    mov si, 0
    mov ah, 2
 
printStr:
    mov dl, ds:[si]
    int 21h
    inc si
    loop printStr
 
    mov ah, 4ch
    int 21h
 
strUp:
    mov al, byte ptr ds:[si]
    cmp al, 'a'
    jb back
    cmp al, 'z'
    ja back
    sub al, 20h
    mov ds:[si], al
     
back:
    ret
 
code ends
end start

运行结果如下：

原数据：

 

 大写转换以后：

 

 

实验任务5

task5.asm源码

assume cs:code, ds:data

data segment
    str1 db "yes", '$'
    str2 db "no", '$'
data ends

code segment
start:
    mov ax, data
    mov ds, ax

    mov ah, 1
    int 21h

    mov ah, 2
    mov bh, 0
    mov dh, 24
    mov dl, 70
    int 10h

    cmp al, '7'
    je s1
    mov ah, 9
    mov dx, offset str2
    int 21h

    jmp over

s1: mov ah, 9
    mov dx, offset str1
    int 21h
over:  
    mov ah, 4ch
    int 21h
code ends
end start

测试结果如下：

 

 问题：程序的功能是？

　　功能是判断输入字符是否为‘7’，是的话输出yes，否则输出no

 

实验任务6

task6_1.asm源码

assume cs:code

code segment
start:
    ; 42 interrupt routine install code
    mov ax, cs
    mov ds, ax
    mov si, offset int42  ; set ds:si

    mov ax, 0
    mov es, ax
    mov di, 200h        ; set es:di

    mov cx, offset int42_end - offset int42
    cld
    rep movsb

    ; set IVT(Interrupt Vector Table)
    mov ax, 0
    mov es, ax
    mov word ptr es:[42*4], 200h
    mov word ptr es:[42*4+2], 0

    mov ah, 4ch
    int 21h

int42: 
    jmp short int42_start
    str db "welcome to 2049!"
    len equ $ - str

    ; display string "welcome to 2049!"
int42_start:
    mov ax, cs
    mov ds, ax
    mov si, 202h

    mov ax, 0b800h
    mov es, ax
    mov di, 24*160 + 32*2

    mov cx, len
s:  mov al, [si]
    mov es:[di], al
    mov byte ptr es:[di+1], 2
    inc si
    add di, 2
    loop s

    iret
int42_end:
   nop
code ends
end start

task6_2.asm源码

assume cs:code

code segment
start:
    int 42

    mov ah, 4ch
    int 21h
code ends
end start

运行结果如下：

 

 实验理解：