在Python中：

def select(x):
    y = []
    for e in x:
        if e!=0:
            y.append(e)
    return y

适用于：

x = [1,0,2,0,0,3]
select(x)
[1,2,3]

被翻译成Fortran：

function select(x,n) result(y)
    implicit none
    integer:: x(n),n,i,j,y(?)
    j = 0
    do i=1,n
        if (x(i)/=0) then
            j = j+1
            y(j) = x(i)
        endif
    enddo
end function

问题出在Fortran中：

>如何申报y(？)？
>如何声明x的预定义值
>如何避免尺寸信息

对于1如果定义为y(n),则输出将为：

x = (/1,0,2,0,0,3/)
print *,select(x,6)
1,2,3,0,0,0

这是不希望的！
！——————————-
评论：
1-所有给出的答案在本文中都很有用.特别是M.S.B和eryksun的.
2-我试图调整我的问题的想法,并用F2Py编译,但它没有成功.我已经使用GFortran对它们进行了调试,所有这些都是成功的.它可能是F2Py中的一个错误或者我不知道正确使用它的东西.我将尝试在另一篇文章中介绍此问题.

更新：
一个链接的问题可以在here找到.

解决方法:

我希望一个真正的Fortran程序员出现,但在没有更好的建议的情况下,我只会指定形状而不是x(:)的大小,使用临时数组temp(size(x)),并使输出y分配.然后在第一次传递之后,分配(y(j))并复制临时数组中的值.但是我不能强调我不是Fortran程序员,因此我不能说该语言是否具有可扩展的数组或者是否存在后者的库.

program test
    implicit none
    integer:: x(10) = (/1,0,2,0,3,0,4,0,5,0/)
    print "(10I2.1)", select(x)

contains

    function select(x) result(y)
        implicit none
        integer, intent(in):: x(:) 
        integer:: i, j, temp(size(x))
        integer, allocatable:: y(:)

        j = 0
        do i = 1, size(x)
            if (x(i) /= 0) then
                j = j + 1
                temp(j) = x(i)
            endif
        enddo

        allocate(y(j))
        y = temp(:j)
    end function select

end program test

编辑：

根据M.S.B.的答案,这里是一个修订版本的函数,它会随着过度分配而增长.和之前一样,它将结果复制到y.事实证明,我没有必要以最终大小显式分配新数组.相反,它可以通过分配自动完成.

    function select(x) result(y)
        implicit none
        integer, intent(in):: x(:) 
        integer:: i, j, dsize
        integer, allocatable:: temp(:), y(:)

        dsize = 0; allocate(y(0))

        j = 0
        do i = 1, size(x)
            if (x(i) /= 0) then
                j = j + 1

                if (j >= dsize) then         !grow y using temp
                    dsize = j + j / 8 + 8 
                    allocate(temp(dsize))
                    temp(:size(y)) = y
                    call move_alloc(temp, y) !temp gets deallocated
                endif

                y(j) = x(i)
            endif
        enddo
        y = y(:j)
    end function select