FOR %variable IN (set) DO command [command-parameters]

  %variable          # Specifies a single letter replaceable parameter. ;指定一个单一字母可替换的参数，简单的说就是vaiable取值范围只能是a~z和A~Z中的一个字母。
                       FOR 变量是单一字母、分大小写 是全局的变量,所以不能同时使用超过 52 个

  (set)              # Specifies a set of one or more files.  Wildcards may be used. ;指定一个或一组文件。可以使用通配符。

  command            # Specifies the command to carry out for each file. ;指定对每个文件执行的命令。

  command-parameters # Specifies parameters or switches for the specified command. ;为特定命令指定参数或命令行开关。

To use the FOR command in a batch program, specify %%variable instead of %variable.  Variable names are case sensitive, so %i is different from %I.

在批处理程序中使用 FOR 命令时，指定变量请使用 %%variable 而不要用 %variable。变量名称是区分大小写的，所以 %i 不同于 %I.
例如 echo %%T  echo 是 command, %%T 则是 echo 的 command-parameters

@echo off

for %%i in (1,2,3,4) do del %%i.txt

pause

@echo off

for %%i in (*.txt) do del %%i

pause

 /d    # Directory ;操作目录

 /r    # Recursion ;递归目录,操作所有目录下的文件

 /f    # File      ;操作文件和字符串

 /l    # Iteration ;迭代器,产生有序序列

FOR /D %variable IN (set) DO command [command-parameters]

If set contains wildcards, then specifies to match against directory names instead of file names.

如果集中包含通配符，则指定与目录名匹配，而不与文件名匹配,只能显示当前目录下的目录名字

@echo off

cd c:

for /d %%T in (*) Do echo %%T

pause

@echo off

cd c:

for /d %%T in (P*) Do echo %%T

pause

@echo off

cd c:

for /d %%T in (???) Do echo %%T

pause

@echo off

cd c:

for /d %%T in (P*, W*) Do echo %%T

pause

@echo off

cd c:

for /d %%T in (P*, ???) Do echo %%T

pause

FOR /R [[drive:]path] %variable IN (set) DO command [command-parameters]

Walks the directory tree rooted at [drive:]path, executing the FOR statement in each directory of the tree.  
If no directory specification is specified after /R then the current directory is assumed.  
If set is just a single period (.) character then it will just enumerate the directory tree.

检查以 [drive:]path 为根的目录树，指向每个目录中的 FOR 语句。

如果在 /R 后没有指定目录规范，则使用当前目录。
如果集仅为一个单点(.)字符，则枚举该目录树,即只操作文件夹,不操作文件。

@echo off

for /r c:\ %%T in (*.exe) do echo %%T

pause

@echo off

for /r %%T in (*.exe) do echo %%T

pause

@echo off
for /r c:\ %%T in (.) Do echo %%T

pause

FOR /L %variable IN (start,step,end) DO command [command-parameters]

The set is a sequence of numbers from start to end, by step amount.

So (1,1,5) would generate the sequence 1 2 3 4 5 and (5,-1,1) would generate the sequence (5 4 3 2 1)

该集表示以增量形式从开始到结束的一个数字序列。
因此，(1,1,5)将产生序列1 2 3 4 5，(5,-1,1)将产生序列(5 4 3 2 1)
总结来说,就是等差数列.

@echo off

for /l %%i in (1,1,5) do echo %%i

pause

@echo off

for /l %%i in (1,1,5) do start calc

pause

FOR /F ["options"] %variable IN (file-set) DO command [command-parameters]

FOR /F ["options"] %variable IN ("string") DO command [command-parameters]

FOR /F ["options"] %variable IN ('command') DO command [command-parameters]

or, if usebackq option present:

如果使用了usebackq 选项, 处理方式如下

FOR /F ["options"] %variable IN (file-set) DO command [command-parameters]
  FOR /F ["options"] %variable IN ('string') DO command [command-parameters]
  FOR /F ["options"] %variable IN (`command`) DO command [command-parameters]

file-set is one or more file names.  Each file is opened, read and processed before going on to the next file in file-set.

Processing consists of reading in the file, breaking it up into individual lines of text and then parsing each line into zero or more tokens.  
The body of the for loop is then called with the variable value(s) set to the found token string(s).  
By default, /F passes the first blank separated token from each line of each file.

Blank lines are skipped.  You can override the default parsing behavior by specifying the optional "options" parameter.  
This is a quoted string which contains one or more keywords to specify different parsing options.  The keywords are:

file-set 为一个或多个文件名。继续到 file-set 中的下一个文件之前，每份文件都被打开、读取并经过处理。处理包括读取文件，将其分成一行行的文字，

然后将每行解析成零或更多的符号。然后用已找到的符号字符串变量值调用 For 循环。

默认方式，/F 通过每个文件的每一行中分开的第一个空白符号。跳过空白行。您可通过指定可选 "options" 参数替代默认解析操作。
这个带引号的字符串包括一个或多个指定不同解析选项的关键字。这些关键字为:

eol=c           # specifies an end of line comment character(just one) ;指一个行注释字符的结尾(就一个)

skip=n          # specifies the number of lines to skip at the beginning of the file.指在文件开始时忽略的行数。

delims=xxx      # specifies a delimiter set.  This replaces the default delimiter set of space and tab. 指定分隔符集。这个替换了空格和跳格键的默认分隔符集。

tokens=x,y,m-n  # specifies which tokens from each line are to be passed to the for body for each iteration.

                  This will cause additional variable names to be allocated.  The m-n form is a range,specifying the mth through the nth tokens.

                  If the last character in the tokens= string is an asterisk, 
                  then an additional variable is allocated and receives the remaining text on the line after the last token parsed.
                  指每行的哪一个符号被传递到每个迭代的 for 本身。这会导致额外变量名称的分配。m-n格式为一个范围。通过 nth 符号指定 mth。
                  如果符号字符串中的最后一个字符星号，那么额外的变量将在最后一个符号解析之后分配并接受行的保留文本

usebackq        # specifies that the new semantics are in force,where a back quoted string is executed as a command and 
                  a single quoted string is a literal string command and allows the use of double quotes to quote file names in filenameset.
                  指定新语法已在下类情况中使用:在作为命令执行一个后引号的字符串并且一个单引号字符为文字字符串命令并允许在 file-set中使用双引号扩起文件名称。
                  微软给出的解释似乎狗屁不通,这个选项的具体用法见下面的例子.

#不使用 usebackq 选项
FOR /F ["options"] %variable IN (file-set) DO command [command-parameters]   # 处理文件, 文件在file-set文件集合中,注意,文件名和路径中都不可以有空格,不能用双引号括起来,否则需要使用usebackq选项

FOR /F ["options"] %variable IN ("string") DO command [command-parameters]   # 处理字符串, 要处理的字符串就是双引号括起来的内容

FOR /F ["options"] %variable IN ('command') DO command [command-parameters]  # 处理命令的结果, 在DO 后面的command执行之前先执行括号中用单引号括起来的命令,该命名的输出结果作为for的输入

The_First_Line

The_Second_Line

The_Thrid_Line

The_Fourth_Line

@echo off

for /f %%T in (C:\myfile1.txt) do echo %%T

pause

第1行第1列 第1行第2列 第1行第3列 

第2行第1列 第2行第2列 第2行第3列 

第3行第1列 第3行第2列 第3行第3列

第1行第1列

第2行第1列

第3行第1列

@echo off

for /f "delims=     " %%T in (C:\myfile2.txt) do echo %%T

pause

第1行第1列,第1行第2列,第1行第3列

第2行第1列,第2行第2列,第2行第3列

第3行第1列,第3行第2列,第3行第3列

@echo off

for /f "delims=," %%T in (C:\myfile3.txt) do echo %%T

pause

@echo off

for /f "tokens=2 delims=," %%T in (myfile3.txt) do echo %%T

pause

@echo off

for /f "tokens=2,3 delims=," %%i in (myfile3.txt) do @echo %%i %%j

pause

@echo off

for /f "tokens=1,2,3 delims=," %%i in (myfile3.txt) do @echo %%i %%j %%k

pause

@echo off

for /f "tokens=* delims=," %%i in (myfile3.txt) do @echo %%i

pause

#这是第1个注释

第1行第1列,第1行第2列,第1行第3列

#这是第2个注释

第2行第1列,第2行第2列,第2行第3列

#这是第3个注释

第3行第1列,第3行第2列,第3行第3列

@echo off

for /f "eol=# tokens=* delims=," %%i in (myfile4.txt) do @echo %%i

pause

NoUseLine1

NoUseLine2

#这是第1个注释

第1行第1列,第1行第2列,第1行第3列

#这是第2个注释

第2行第1列,第2行第2列,第2行第3列

#这是第3个注释

第3行第1列,第3行第2列,第3行第3列

@echo off

for /f "eol=# skip=2 tokens=* delims=," %%i in (myfile5.txt) do @echo %%i

pause

@echo off

for /f "tokens=2,3 delims=," %%i in ("第1行第1列,第1行第2列,第1行第3列") do @echo %%i %%j

pause

@echo off

for /f "tokens=1 delims==" %%i in ('set') do @echo %%i

pause

#使用 usebackq 选项,该选项在"options"中

FOR /F ["options"] %variable IN (file-set) DO command [command-parameters]   # 处理文件, 文件名和路径中都可以有空格,必须用双引号括起来

FOR /F ["options"] %variable IN ('string') DO command [command-parameters]   # 处理字符串, 要处理的字符串就是单引号括起来的内容

FOR /F ["options"] %variable IN (`command`) DO command [command-parameters]  # 处理命令的结果, 在DO 后面的command执行之前先执行括号中用后引号括起来的命令,该命名的输出结果作为for的输入 

@echo off

for /f "usebackq" %%T in (“C:\Program Files\my file1.txt") do echo %%T

pause

@echo off

for /f "tokens=2,3 delims=, usebackq" %%i in ('第1行第1列,第1行第2列,第1行第3列') do @echo %%i %%j

pause

@echo off

for /f "tokens=1 delims== usebackq" %%i in (`set`) do @echo %%i

pause

@echo off

for /f "tokens=1 delims== usebackq" %%i in (`set`) do (

echo ------------------------------------------------

echo %%i

)

pause

    %~I         # expands %I removing any surrounding quotes (") ;删除任何引号(")

    %~fI        # expands %I to a fully qualified path name ;将 %I 扩展到一个完全合格的路径名

    %~dI        # expands %I to a drive letter only ;仅将 %I 扩展到一个驱动器号

    %~pI        # expands %I to a path only ;仅将 %I 扩展到一个路径

    %~nI        # expands %I to a file name only ;仅将 %I 扩展到一个文件名

    %~xI        # expands %I to a file extension only ;仅将 %I 扩展为文件后缀名

    %~sI        # expanded path contains short names only ;将 %I 扩展到文件的文件属性

    %~aI        # expands %I to file attributes of file ;将 %I 扩展到文件的日期/时间

    %~tI        # expands %I to date/time of file ;将 %I 扩展到文件的大小

    %~zI        # expands %I to size of file ;将 %I 扩展到文件的大小

    %~$PATH:I   # searches the directories listed in the PATH environment variable

                  and expands %I to the fully qualified name of the first one found.

                  If the environment variable name is not defined or the file is not found by the search,

                  then this modifier expands to the empty string

                  ;查找 PATH 环境变量中的目录，并将 %I 扩展到找到的第一个完全合格的名称。

                  如果环境变量名未被定义，或者没有找到文件，此组合键会扩展到空字符串

The modifiers can be combined to get compound results:

可以组合修饰符来得到多重结果:

    %~dpI       # expands %I to a drive letter and path only ;仅将 %I 扩展到一个驱动器号和路径

    %~nxI       # expands %I to a file name and extension only ;仅将 %I 扩展到一个文件名和扩展名

    %~fsI       # expands %I to a full path name with short names only ;仅将 %I 扩展到一个带有短名的完整路径名

    %~dp$PATH:I # searches the directories listed in the PATH environment variable for %I and expands to the drive letter and path of the first one found.

                  ;搜索列在路径环境变量的目录，并将 %I 扩展到找到的第一个驱动器号和路径。

    %~ftzaI     # expands %I to a DIR like output line ;将 %I 扩展到类似输出线路的 DIR

In the above examples %I and PATH can be replaced by other valid

values.  The %~ syntax is terminated by a valid FOR variable name.

Picking upper case variable names like %I makes it more readable and

avoids confusion with the modifiers, which are not case sensitive.

在以上例子中，%I 和 PATH 可用其他有效值代替。

%~ 遇到一个有效的 FOR 变量名终止。选取类似 %I 的大写变量名比较易读，而且避免与不分大小写的组合键混淆。

"First", "Second","Thrid"

@echo offfor /f  "delims=, usebackq" %%T in ("C:\Program Files\my file.txt") do (

    echo ---Original

    echo %%T

    echo ----expands %I removing any surrounding quotes

    echo %%~T

    echo ----expands %I to a fully qualified path name

    echo %%~fT

    echo ----expands %I to a drive letter only

    echo %%~dT

    echo ----expands %I to a path only

    echo %%~pT

    echo ----expands %I to a file name only

    echo %%~nT

    echo ----expanded path contains short names only

    echo %%~sT

    echo ----expands %I to a drive letter and path only

    echo %%~dpT

    echo ----expands %I to a full path name with short names only

    echo %%~fsT

    echo ----expands %I to a file name and extension only

    echo %%~nxT

    echo ----expands %I to a DIR like output line

    echo %%~ftzaT
)
pause

---Original
"First"
----expands I removing any surrounding quotes
First
----expands I to a fully qualified path name
c:\Batch\First
----expands I to a drive letter only
c:
----expands I to a path only
\Batch\
----expands I to a file name only
First
----expanded path contains short names only
c:\Batch\First
----expands I to a drive letter and path only
c:\Batch\
----expands I to a full path name with short names only
c:\Batch\First
----expands I to a file name and extension only
First